Support Power Platform - Apps - Automate - SharePoint - Copilot

Liste SharePoint ou table Dataverse | comparer la syntaxe

Une même donnée, la gravité d'une non-conformité par exemple, ne s'écrit pas de la même façon selon qu'elle vient d'une liste SharePoint ou d'une table Dataverse. Cette page met les deux syntaxes côte à côte, dans Power Apps (formules Power Fx) puis dans Power Automate (filtres OData, jetons et expressions).

💡
Les exemples reprennent l'univers des labs : la liste SharePoint NonConformites du site Qualité Brévalis (colonnes Gravite, Avancement, Atelier, Responsable, DateDetection) et la table Dataverse Non-conformités de la solution QualiteBrevalis (préfixe brv). Les formules Power Fx utilisent le point-virgule comme séparateur, comme dans Power Apps en français.

1. Trois noms pour une même colonne

Dans SharePoint comme dans Dataverse, une colonne a un nom affiché, que l'on peut changer, et un nom technique, figé à la création. Power Apps travaille avec le nom affiché, Power Automate avec le nom technique.

NotionListe SharePointTable Dataverse
Nom affichéGravitéGravité
Nom techniquenom interne : Gravitenom logique : brv_gravit
Règle de formationnom saisi à la création ; une espace devient _x0020_, un accent est encodé (_x00e9_)préfixe de l'éditeur + nom saisi en minuscules, sans les caractères accentués : Gravité donne brv_gravit, Date de détection donne brv_datededtection
Nom de la sourceNonConformites (nom de la liste)nom affiché pluriel Non-conformités (Power Apps), nom logique brv_nonconformite, nom du jeu d'entités brv_nonconformites (Power Automate)
Où le lireParamètres de la liste, clic sur la colonne : fin de l'adresse Field=Gravitemake.powerapps.com, Tables, Colonnes : volet Propriétés avancées, « Nom logique »
Renommer la colonnele nom interne ne change pasle nom logique ne change pas
  • Dans les environnements réels, la colonne affichée Avancement de la table Non-conformités garde le nom logique brv_statut (créée sous le nom Statut puis renommée). Le script de création des labs la crée directement en brv_avancement. Vérifiez toujours le nom logique avant d'écrire un filtre.
  • Dans Dataverse, le nom Statut est déjà pris par la colonne système statecode (Actif, Inactif) : c'est la raison du renommage en Avancement.

2. Power Apps | lire et filtrer une colonne Choix

Dans SharePoint, une colonne Choix renvoie un enregistrement {Value: "Critique"} : on lit sa propriété .Value, du texte. Dans Dataverse, une colonne Choix (anciennement « groupe d'options ») renvoie une valeur d'énumération : on la compare à 'Gravité (Non-conformités)'.Critique, jamais à un texte.

BesoinListe SharePointTable Dataverse
Afficher la valeurThisItem.Gravite.ValueText(ThisItem.Gravité)
Filtrer sur une valeurFilter(NonConformites; Gravite.Value = "Critique")Filter('Non-conformités'; Gravité = 'Gravité (Non-conformités)'.Critique)
Retrouver une ficheLookUp(NonConformites; Gravite.Value = "Critique")LookUp('Non-conformités'; Gravité = 'Gravité (Non-conformités)'.Critique)
Alimenter une liste déroulante (Items)Choices([@NonConformites].Gravite)Choices('Gravité (Non-conformités)')
Tester la valeur choisiedrpGravite.Selected.Value = "Critique"drpGravite.Selected.Value = 'Gravité (Non-conformités)'.Critique
Valeur stockéele texte du libelléun entier (ici 990800000, 990800001, 990800002)
  • Le nom 'Gravité (Non-conformités)' désigne le choix local de la colonne. Si la colonne utilise un choix global, on écrit le nom du choix global, par exemple 'Gravité NC'.Critique.
  • Si le nom affiché de la colonne et celui du choix sont identiques, ajoutez [@...] pour désigner le choix : [@'Gravité'].Critique.
  • Avec Dataverse, l'éditeur de formules propose les valeurs dès que l'on tape le point : une faute de frappe est signalée tout de suite, alors qu'un texte mal orthographié dans SharePoint donne simplement une galerie vide.

3. Power Apps | écrire avec Patch

ColonneListe SharePointTable Dataverse
Choix{Gravite: {Value: "Critique"}}{Gravité: 'Gravité (Non-conformités)'.Critique}
Avancement{Avancement: {Value: "Clôturée"}}{Avancement: 'Avancement (Non-conformités)'.Clôturée}
Recherche (lookup){Atelier: {Id: 3; Value: "Assemblage Lamballe"}}{Atelier: LookUp(Ateliers; Nom = "Assemblage Lamballe")}
Date{DateDetection: Today()}{'Date de détection': Today()}
Nouvelle fichePatch(NonConformites; Defaults(NonConformites); {...})Patch('Non-conformités'; Defaults('Non-conformités'); {...})

Exemple complet, celui des labs CD01 et CD03 :

// SharePoint : clôturer la fiche sélectionnée
Patch(NonConformites; galNC.Selected; {Avancement: {Value: "Clôturée"}})

// Dataverse : passer en Critique et rattacher à un atelier
Patch('Non-conformités'; galNC.Selected;
    {Gravité: 'Gravité (Non-conformités)'.Critique;
     Atelier: LookUp(Ateliers; Nom = "Assemblage Lamballe")})
  • SharePoint attend pour une recherche un enregistrement avec Id (numéro de l'élément de la liste Ateliers) et Value (texte de la colonne affichée).
  • Dataverse attend l'enregistrement complet de la table liée : on le récupère avec LookUp ou on prend drpAtelier.Selected.

4. Power Apps | colonnes Recherche et Personne

BesoinListe SharePointTable Dataverse
Lire la rechercheThisItem.Atelier.Value (texte seulement)ThisItem.Atelier.Nom (toute colonne de l'atelier est accessible)
Filtrer sur la rechercheFilter(NonConformites; Atelier.Value = "Assemblage Lamballe")Filter('Non-conformités'; Atelier.Nom = "Assemblage Lamballe") ou Atelier = drpAtelier.Selected
Type d'une personnecolonne Personne (enregistrement Claims, DisplayName, Email...)pas de type Personne : une recherche vers la table Utilisateurs, ou la colonne système Propriétaire
Lire la personneThisItem.Responsable.DisplayNameThisItem.Propriétaire.'Nom complet'
Filtrer sur l'utilisateur connectéFilter(NonConformites; Responsable.Email = User().Email)Filter('Non-conformités'; Propriétaire.'Adresse e-mail principale' = User().Email)

Écrire une personne :

// SharePoint : les six champs sont attendus, même vides
Patch(NonConformites; Defaults(NonConformites);
    {Titre: txtTitreRapide.Text;
     Responsable: {Claims: "i:0#.f|membership|" & Lower(User().Email);
                   Department: ""; DisplayName: User().FullName;
                   Email: User().Email; JobTitle: ""; Picture: ""}})

// Dataverse : un enregistrement de la table Utilisateurs
Patch('Non-conformités'; galNC.Selected;
    {Propriétaire: LookUp(Utilisateurs; 'Adresse e-mail principale' = User().Email)})

5. Power Apps | délégation

Une formule non délégable ne lit que les premières lignes de la source (la limite de lignes de données : 500 par défaut, réglable jusqu'à 10 000 dans Paramètres), puis filtre sur l'appareil. Les deux sources ne délèguent pas les mêmes opérations.

OpérationListe SharePointTable Dataverse
= sur un Choixoui (Gravite.Value = "Critique")oui
<, > sur un Choixnonnon
<, > sur du textenonoui
StartsWithoui sur du texte, non sur .Value d'un Choix ou d'une rechercheoui sur du texte
Searchnonoui sur les colonnes texte
Not(...)nonoui
IsBlank(colonne)non (écrire colonne = Blank())oui sauf sur un Choix
Month('Date de détection') = Month(Today())nonnon
'Date de détection' >= Date(Year(Today()); Month(Today()); 1)ouioui
Personneoui sur Email et DisplayNamesans objet (recherche Utilisateurs)
In (appartenance)nonoui
  • Exemple du lab CD04 : la première formule déclenche le triangle jaune, la seconde est délégable dans les deux sources.
// Non délégable : Month() s'applique à la colonne
Sort(Filter('Non-conformités'; Month('Date de détection') = Month(Today()));
    'Date de détection'; SortOrder.Descending)

// Délégable : la colonne est comparée à une valeur calculée
Sort(Filter('Non-conformités'; 'Date de détection' >= Date(Year(Today()); Month(Today()); 1));
    'Date de détection'; SortOrder.Descending)

6. Power Automate | où se place le filtre

BesoinSharePointDataverse
Lire plusieurs fichesaction Obtenir les éléments, champ Requête de filtreaction Lister les lignes, champ Filtrer les lignes
Trierchamp Trier par : DateDetection descchamp Trier par : brv_datededtection desc
Limiter les colonnespas de champ (toutes les colonnes de l'affichage choisi)champ Sélectionner des colonnes : brv_titre,brv_gravit
Nombre de fichesNombre supérieur : 100 par défaut, 5 000 au plus sans paginationNombre de lignes ; 5 000 lignes par page, pagination au-delà
Filtrer le déclencheurpas de filtre OData : Conditions de déclenchement (expression) dans les paramètres du déclencheurchamp Lignes de filtre du déclencheur « Lorsqu'une ligne est ajoutée, modifiée ou supprimée »
  • Dans les deux cas, on n'écrit pas $filter= : seulement la condition.
  • Dans Dataverse, les champs Lignes de filtre (déclencheur) et Filtrer les lignes (action) acceptent la même syntaxe.

7. Power Automate | syntaxe du filtre OData

BesoinRequête de filtre SharePointFiltrer les lignes Dataverse
Nom de colonnenom interne : Gravitenom logique : brv_gravit
Choix égal àGravite eq 'Critique' (le libellé, entre apostrophes)brv_gravit eq 990800002 (l'entier, sans apostrophes)
Choix différent deAvancement ne 'Clôturée'brv_statut ne 990800003 (ou brv_avancement, selon l'environnement)
TexteTitle eq 'Fuite vérin presse 3'brv_titre eq 'Fuite vérin presse 3'
Commence parstartswith(Title, 'Fuite')startswith(brv_titre, 'Fuite')
Contientsubstringof('vérin', Title)contains(brv_titre, 'vérin')
Recherche, par libelléAtelier/Title eq 'Assemblage Lamballe'brv_Atelier/brv_nom eq 'Assemblage Lamballe' (propriété de navigation, sensible à la casse)
Recherche, par identifiantAtelierId eq 3_brv_atelier_value eq 6f1c... (GUID sans apostrophes)
PersonneResponsable/EMail eq 'camille.lefort@brevalis.fr'_ownerid_value eq 9a2b... (GUID de l'utilisateur)
DateDateDetection ge '2026-11-01' (entre apostrophes)brv_datededtection ge 2026-11-01 (sans apostrophes)
Date relativeexpression : DateDetection ge '@{formatDateTime(addDays(utcNow(), -7), 'yyyy-MM-dd')}'fonction Dataverse : Microsoft.Dynamics.CRM.LastXDays(PropertyName='brv_datededtection',PropertyValue=7)
VideResponsable eq null_ownerid_value eq null
Deux conditionsGravite eq 'Critique' and Avancement ne 'Clôturée'brv_gravit eq 990800002 and brv_statut ne 990800003
  • Les opérateurs s'écrivent en minuscules et en anglais : eq, ne, gt, ge, lt, le, and, or.
  • Les valeurs texte prennent des apostrophes droites ', jamais des guillemets ni l'apostrophe typographique ’ (message d'erreur du lab PA04).
  • Les entiers des choix (990800000, 990800001...) se lisent dans make.powerapps.com, colonne Gravité, Modifier le choix, onglet Valeur. Le préfixe 99080 vient de l'éditeur Brévalis Industries.
  • Dans Dataverse, un caractère comme &, # ou + doit être encodé dans une valeur texte.
  • Les valeurs des choix Avancement suivent l'ordre de création (Ouverte, En cours, À clôturer, Clôturée) : vérifiez l'entier de Clôturée avant de l'utiliser.

Labs : [Lab PA04] Envoyer une synthèse hebdomadaire des non-conformités (Avancement ne 'Clôturée'), [Lab DA02] Filtrer les lignes du déclencheur (brv_gravit eq 990800002), [Lab DA04] Lister des lignes dans un flux (même filtre, trié par brv_datededtection desc).

8. Power Automate | lire les valeurs dans les jetons

DonnéeJeton ou expression SharePointJeton ou expression Dataverse
Libellé d'un choixjeton Gravite Value : triggerOutputs()?['body/Gravite/Value']triggerOutputs()?['body/brv_gravit@OData.Community.Display.V1.FormattedValue']
Valeur stockée d'un choixle libellé (même jeton)jeton Gravité : triggerOutputs()?['body/brv_gravit'] donne 990800002
Recherchejetons Atelier Value (texte) et Atelier Id (numéro)jeton _brv_atelier_value (GUID) ; libellé par ...['body/_brv_atelier_value@OData.Community.Display.V1.FormattedValue']
Personnejetons Responsable DisplayName, Responsable Email, Responsable Claims_ownerid_value (GUID) et son FormattedValue (nom complet)
Datebody/DateDetection (format ISO)body/brv_datededtection (format ISO, en UTC)
Identifiant de la ficheID (entier)Non-conformité : brv_nonconformiteid (GUID)
  • Dans Dataverse, FormattedValue est une propriété à part entière du corps : on la lit par son nom complet, avec le chemin body/. Dans une boucle sur Lister les lignes, on écrit items('Appliquer_à_chacun')?['brv_gravit@OData.Community.Display.V1.FormattedValue'].
  • Dans un e-mail, utilisez le libellé (FormattedValue ou Value) ; dans une condition, comparez de préférence l'entier Dataverse, qui ne change pas si l'on renomme le libellé.

9. Power Automate | écrire une fiche

ColonneCréer l'élément / Mettre à jour l'élément (SharePoint)Ajouter une nouvelle ligne / Mettre à jour une ligne (Dataverse)
Choixchamp Gravite Value : choisir Critique, ou saisir le texte Critiquechamp Gravité : choisir Critique, ou saisir l'entier 990800002
Recherchechamp Atelier Id : le numéro de l'élément, 3champ Atelier : brv_ateliers(6f1c...), nom du jeu d'entités puis GUID entre parenthèses
Personnechamp Responsable Claims : l'adresse de messageriechamp Propriétaire : systemusers(9a2b...)
Fiche à modifierId : entierID de ligne : GUID seul (jeton Non-conformité)
  • Dans Dataverse, passer le GUID seul dans un champ de recherche provoque l'erreur « Resource not found for the segment » : il faut le nom du jeu d'entités devant. Ce nom se copie dans make.powerapps.com, table Ateliers, Outils, Copier le nom du jeu.
  • À l'inverse, le champ ID de ligne de Mettre à jour une ligne attend le GUID seul, sans nom de table.

10. Mémo des pièges

PiègeCe qui se passeCorrection
Écrire Gravité dans une Requête de filtrecolonne inconnuenom interne Gravite
Écrire brv_gravite dans Filtrer les lignescolonne inconnuenom logique sans accent : brv_gravit
Comparer un choix Dataverse à 'Critique' dans l'ODataerreur de typeentier 990800002
Comparer un choix Dataverse à "Critique" dans Power Appsformule en erreur'Gravité (Non-conformités)'.Critique
Oublier .Value sur un choix SharePoint dans Power Appscomparaison d'un enregistrement à un texteGravite.Value = "Critique"
Guillemets ou apostrophe typographique dans l'ODataerreur de syntaxeapostrophes droites '
Filtrer sur Statut dans Dataversefiltre sur Actif / Inactif (statecode)colonne Avancement (brv_statut ou brv_avancement)
GUID seul dans un champ de recherche DataverseResource not found for the segmentbrv_ateliers(GUID)
Month() ou Not() sur une liste SharePointtriangle jaune, résultats incomplets au-delà de 500 lignescomparer la colonne à une valeur calculée

Labs associés

LabCe qu'il illustre
[Lab CV04] Afficher les non-conformités dans une galerieThisItem.Gravite.Value dans une galerie SharePoint
[Lab CD01] Écrire dans SharePoint avec PatchPatch SharePoint : Choix {Value: ...} et Personne Claims
[Lab CD02] Créer des listes déroulantes en cascadeChoices et filtre sur une recherche SharePoint
[Lab CD03] Connecter l'application à DataversePatch Dataverse : 'Gravité (Non-conformités)'.Critique et enregistrement Atelier
[Lab CD04] Comprendre la délégationDélégation
[Lab PA02] Orienter une non-conformité selon sa gravitéJeton Gravite Value
[Lab PA04] Envoyer une synthèse hebdomadaire des non-conformitésRequête de filtre Avancement ne 'Clôturée'
[Lab DA01] Déclencher un flux sur une nouvelle ligneSorties brutes du déclencheur Dataverse
[Lab DA02] Filtrer les lignes du déclencheurLignes de filtre brv_gravit eq 990800002 et FormattedValue
[Lab DA03] Ajouter et mettre à jour des lignes depuis un fluxAjouter et mettre à jour une ligne
[Lab DA04] Lister des lignes dans un fluxLister les lignes : filtre, tri, colonnes